-- card: 5379 from stack: in
-- bmap block id: 0
-- flags: 0000
-- background id: 2114
-- name: 
----- HyperTalk script -----
on openCard
  checkDate
  -- checkDate is written as a separate handler so it will work
  -- with HyperDA which will skip it this way instead of going
  -- into a loop
  exit openCard
end openCard

on checkDate
  put the date into today
  convert today to seconds
  put "11/4/90" into effDate
  convert effDate to seconds
  if today ≥ effDate and background field "Area Code" is "214" then
    put "The 214 area code split into two area codes on 11/4/90"
    answer "Create new 903 Area Code? (see msg box)" with Cancel or OK
    if it is "Cancel" then exit checkDate
    --temporairly change the AC as an update in progress indicator
    put "214x" into field "Area Code"
    set the script of this card to empty
    -- user level must be ≥ 3 (painting) to allow copy card
    put the userLevel into saveULev
    set the userLevel to 3
    -- create a new card for the new area code
    doMenu "Copy Card"
    find "817" in field "Area Code"
    doMenu "Paste Card"
    set the userLevel to saveULev
    put "903" into field "Area Code"
    put "Texas, Tyler" into field "region"
    -- find the first line of locations that go with new area code
    find "Bonham,"
    if fld "Area Code" is not "903" or the foundText is empty then
      answer "Problem creating new Area code card"
      exit checkDate
    end if
    -- delete locations above that are still in the old area code
    put word 2 of the foundLine into tmp1
    repeat tmp1 - 1 times
      delete line 1 of field "locations"
    end repeat
    put return & "Note: This area code was split from the 214 area code in 1990" & return before line 2 of fld "locations"
    -- find the old area code card
    find "214x" in field "Area Code"
    put "214" into field "Area Code"  --change back from 214x
    -- delete locations below Note: that are in the new area code
    find "Note:" in fld "locations"
    if fld "Area Code" is not "214" or the foundText is empty then
      answer "Problem editing Area code card"
      exit checkDate
    end if
    put word 2 of the foundLine into tmp2
    repeat with i = tmp2 to number of lines in fld "locations"
      put empty into line i of field "locations"
    end repeat
  end if
end checkDate


-- part contents for background part 1
----- text -----
214

-- part contents for background part 2
----- text -----
GMT -6 (Central)

-- part contents for background part 3
----- text -----
Texas, Dallas

-- part contents for background part 4
----- text -----
Dallas,  Garland, Grand Prairie, Highland Park, Irving, Mesquite, Plano, Richardson

Note: The following locations will move to new area code (903) on Nov. 4, 1990. 

Bonham, Carthage, Denison,  Greenville, Longview, Marshal, Mineola, Paris, Sherman, Sulphur Springs, Texarkana, Tyler
Permissive dialing  will allow access by dialing either area code until 5/5/91.




-- part contents for background part 14
----- text -----
USA

-- part contents for background part 16
----- text -----
1